HubFormation Page d'accueil
Vous êtes ici :  Accueil > Blogue > Ajustements pour faire le tutoriel de visuel de cartes de Microsoft

Ajustements pour faire le tutoriel de visuel de cartes de Microsoft

Présentation du problème

Microsoft ont récemment lancé un nouveau visuel de cartes (card visual en anglais) qui remplace les cartes à numéro unique et les cartes à plusieurs lignes. Ce visuel est très sophistiqué, alors il est bon de se documenter pour comprendre les différentes possibilités et comment le configurer. À cet effet, Microsoft ont créé un tutoriel sur le nouveau visuel de cartes. L’article complet sur leur site est Créer un visuel de carte dans Power BI et le travail que nous allons présenter est lié à la section Guide pas à pas de la carte. Malheureusement, il y a des problèmes avec le code TMDL fourni par Microsoft qui ne fonctionne pas bien quand nous sommes avec une localisation « Français - Canada ». J’ai fait les correctifs pour que ça marche. Le code à insérer se trouve dans les étapes de la prochaine section. À terme, nous voulons obtenir ce résultat :

Figure 1 — Résultat final de notre visuel de carte. C’est une des versions du visuel présentée dans le tutoriel et c’est sur celle-là que nous nous attardons dans cet article.

Pour arriver à faire le tutoriel, la fonction qui permet de faire les petits graphiques a été sortie du TMDL : nous devrons donc l’ajouter manuellement dans le modèle. Après il faut ajuster les 4 mesures qui au départ retournent une chaîne de caractère.

Les étapes pour faire ceci sont présentées dans la vidéo d’accompagnement que nous avons mise sur notre chaîne YouTube.

Code nécessaire pour faire les travaux

Le premier morceau de code à amener est le TMDL modifié avec les données et les mesures de base. Malgré tous mes efforts, je n’ai pas réussi à y intégrer la fonction définie par l’utilisateur (user defined function ou UDF en anglais) pour le graphique. Comme l’objectif était de faire le tutoriel, j’ai décidé de séparer ce morceau et de l’ajouter à la main. Lorsque la fonction TrendSVG sera dans le modèle, nous pourrons ajuster les 4 mesures (Revenue 6mo trend, Revenue 6mo trend - hover, Units 6mo trend et Units 6mo trend - hover) qui au départ avec notre version du TMDL retournent une simple chaîne de caractères.

createOrReplace

 table 'Product Line Sales'

 	/// Total number of products sold across all channels and product lines.
 	measure Units = SUM('Product Line Sales'[_Units])
 		formatString: #,##0

 	/// Total sales revenue generated from all transactions.
 	measure Revenue = SUM('Product Line Sales'[_Revenue])
 		formatString: $#,##0

 	/// The planned revenue goal used to measure sales performance.
 	measure 'Revenue target' = SUM('Product Line Sales'[_Revenue Target])
 		formatString: $#,##0

 	/// Total number of products returned by customers.
 	measure Returns = SUM('Product Line Sales'[_Returns])
 		formatString: #,##0

 	/// Shows how close actual revenue is to the target (100% = on target, >100% = exceeding).
 	measure 'Revenue % to target' = DIVIDE([Revenue], [Revenue target])
 		formatString: 0.0%

 	/// Percentage of sold units that were returned (lower is better).
 	measure 'Return rate' = DIVIDE([Returns], [Units])
 		formatString: 0.0%

 	/// Dollar amount above or below the revenue target (positive = exceeding, negative = behind).
 	measure 'Revenue variance' = [Revenue] - [Revenue target]
 		formatString: $#,##0

 	/// Icon showing a # symbol inside a circle to represent units.
 	measure 'Units callout image' = "data:image/svg+xml,%3Csvg xmlns='http://www.w3.org/2000/svg' width='24' height='24' viewBox='0 0 24 24'%3E%3Ccircle cx='12' cy='12' r='10' fill='none' stroke='%230078D4' stroke-width='1.5'/%3E%3Ctext x='12' y='17' text-anchor='middle' font-family='Segoe UI' font-size='14' font-weight='600' fill='%230078D4'%3E%23%3C/text%3E%3C/svg%3E"
 		displayFolder: Card images for callout
 		dataCategory: ImageUrl

 	/// Icon showing a $ symbol inside a circle to represent revenue.
 	measure 'Revenue callout image' = "data:image/svg+xml,%3Csvg xmlns='http://www.w3.org/2000/svg' width='24' height='24' viewBox='0 0 24 24'%3E%3Ccircle cx='12' cy='12' r='10' fill='none' stroke='%23107C10' stroke-width='1.5'/%3E%3Ctext x='12' y='17' text-anchor='middle' font-family='Segoe UI' font-size='14' font-weight='600' fill='%23107C10'%3E%24%3C/text%3E%3C/svg%3E"
 		displayFolder: Card images for callout
 		dataCategory: ImageUrl
		
 	measure 'Revenue 6mo trend' = "TODO"
 		displayFolder: Card images for trendlines

 	measure 'Revenue 6mo trend - hover' = "TODO"
 		displayFolder: Card images for trendlines

 	measure 'Units 6mo trend' = "TODO"
 		displayFolder: Card images for trendlines
		
 	measure 'Units 6mo trend - hover' = "TODO"
 		displayFolder: Card images for trendlines
		
 	column Month
 		formatString: mmm. yyyy
 		summarizeBy: none
 		isNameInferred
 		sourceColumn: [Month]

 		annotation SummarizationSetBy = Automatic

 		annotation PBI_FormatHint = {"isCustom":true}

 	column 'Product Line'
 		summarizeBy: none
 		isNameInferred
 		sourceColumn: [Product Line]

 		annotation SummarizationSetBy = Automatic

 	column Channel
 		summarizeBy: none
 		isNameInferred
 		sourceColumn: [Channel]

 		annotation SummarizationSetBy = Automatic

 	column _Units
 		isHidden
 		formatString: 0
 		summarizeBy: sum
 		isNameInferred
 		sourceColumn: [_Units]

 		annotation SummarizationSetBy = Automatic

 	column _Revenue
 		isHidden
 		formatString: 0
 		summarizeBy: sum
 		isNameInferred
 		sourceColumn: [_Revenue]

 		annotation SummarizationSetBy = Automatic

 	column '_Revenue Target'
 		isHidden
 		formatString: 0
 		summarizeBy: sum
 		isNameInferred
 		sourceColumn: [_Revenue Target]

 		annotation SummarizationSetBy = Automatic

 	column _Returns
 		isHidden
 		formatString: 0
 		summarizeBy: sum
 		isNameInferred
 		sourceColumn: [_Returns]

 		annotation SummarizationSetBy = Automatic

 	partition 'Product Line Sales' = calculated
 		mode: import
 		source = ```
 				   VAR Anchor = DATE(YEAR(TODAY()), MONTH(TODAY()), 1)
 				   VAR M1 = EDATE(Anchor, -5)
 				   VAR M2 = EDATE(Anchor, -4)
 				   VAR M3 = EDATE(Anchor, -3)
 				   VAR M4 = EDATE(Anchor, -2)
 				   VAR M5 = EDATE(Anchor, -1)
 				   VAR M6 = Anchor
 				   RETURN
 				   SELECTCOLUMNS(
 				       {
 				           // Product Line A, Online
 				           ( M1, "A", "Online", 130, 9100, 10000, 5 ),
 				           ( M2, "A", "Online", 200, 14000, 11500, 6 ),
 				           ( M3, "A", "Online", 170, 11900, 13000, 7 ),
 				           ( M4, "A", "Online", 210, 14700, 14000, 8 ),
 				           ( M5, "A", "Online", 230, 16100, 15500, 9 ),
 				           ( M6, "A", "Online", 260, 18200, 16000, 10 ),
 				           // Product Line A, Retail
 				           ( M1, "A", "Retail", 80, 4800, 12000, 35 ),
 				           ( M2, "A", "Retail", 140, 8500, 11000, 30 ),
 				           ( M3, "A", "Retail", 100, 6000, 10500, 27 ),
 				           ( M4, "A", "Retail", 150, 9100, 9500, 24 ),
 				           ( M5, "A", "Retail", 160, 9700, 8500, 21 ),
 				           ( M6, "A", "Retail", 170, 10500, 8500, 17 ),
 				           // Product Line B, Online
 				           ( M1, "B", "Online", 280, 19600, 21000, 10 ),
 				           ( M2, "B", "Online", 380, 26600, 23000, 12 ),
 				           ( M3, "B", "Online", 340, 23800, 24500, 14 ),
 				           ( M4, "B", "Online", 410, 28700, 25500, 16 ),
 				           ( M5, "B", "Online", 470, 32900, 27000, 17 ),
 				           ( M6, "B", "Online", 520, 36400, 29000, 20 ),
 				           // Product Line B, Retail
 				           ( M1, "B", "Retail", 180, 12600, 25000, 140 ),
 				           ( M2, "B", "Retail", 270, 18900, 22000, 125 ),
 				           ( M3, "B", "Retail", 240, 16800, 21000, 110 ),
 				           ( M4, "B", "Retail", 280, 19600, 19000, 100 ),
 				           ( M5, "B", "Retail", 310, 21700, 17000, 90 ),
 				           ( M6, "B", "Retail", 320, 22400, 16000, 75 ),
 				           // Product Line C, Online
 				           ( M1, "C", "Online", 65, 7800, 8000, 2 ),
 				           ( M2, "C", "Online", 100, 12000, 9500, 2 ),
 				           ( M3, "C", "Online", 85, 10200, 11000, 3 ),
 				           ( M4, "C", "Online", 110, 13200, 12500, 3 ),
 				           ( M5, "C", "Online", 115, 13800, 13500, 4 ),
 				           ( M6, "C", "Online", 125, 15000, 15500, 4 ),
 				           // Product Line C, Retail
 				           ( M1, "C", "Retail", 100, 12000, 14000, 4 ),
 				           ( M2, "C", "Retail", 170, 20400, 15500, 4 ),
 				           ( M3, "C", "Retail", 140, 16800, 17000, 5 ),
 				           ( M4, "C", "Retail", 175, 21000, 17500, 5 ),
 				           ( M5, "C", "Retail", 180, 21600, 18000, 6 ),
 				           ( M6, "C", "Retail", 185, 22200, 18000, 7 )
 				       },
 				       "Month", [Value1],
 				       "Product Line", [Value2],
 				       "Channel", [Value3],
 				       "_Units", [Value4],
 				       "_Revenue", [Value5],
 				       "_Revenue Target", [Value6],
 				       "_Returns", [Value7])
 		```

 	annotation PBI_Id = c8632d7dc9194275b03f266beb0eec91

Une fois que le code a été appliqué au rapport, nous avons des données et des mesures dans le modèle et pouvons faire une grande partie du tutoriel de Microsoft. En particulier, nous pouvons mettre des cartes et des catégories. La partie sur les étiquettes de référence et la mise en forme conditionnelle peut aussi être faite. La vidéo et le reste de l’article donne les ajustements à faire si vous voulez faire le visuel avec les graphiques comme mis à la Figure 1.

Pour être en mesure de mettre les graphiques, nous devons d’abord injecter le code pour la UDF. Cette fonction prend une mesure en paramètre (qui sera passée par référence) et a aussi un booléen en dernier argument pour dire si on veut le graphique avec la mise en évidence au pointage ou non (paramètre hover). Notre vidéo montre comment ajouter la fonction suivante dans le modèle.

TrendSVG = 
(
  valueExpr:  ANYREF EXPR,
  periodCol:  ANYREF EXPR,
  periods:    INT64,
  labelChars: INT64,
  dateFormat: STRING,
  hover:      BOOLEAN
) =>
  VAR _LastPeriod = MAX ( periodCol )
  VAR _BasePeriods =
    TOPN (
      periods,
      FILTER ( ALL ( periodCol ), periodCol <= _LastPeriod ),
      periodCol,
      DESC
    )
  VAR _Data =
    ADDCOLUMNS (
      _BasePeriods,
      "Value",
        VAR _v = CALCULATE ( valueExpr )
        RETURN IF ( ISBLANK ( _v ), 0, _v )
    )
  VAR _DataIndexed =
    ADDCOLUMNS (
      _Data,
      "Idx",
        RANKX ( _Data, periodCol, periodCol, ASC, DENSE ),
      "PeriodLabel",
        UPPER ( LEFT ( FORMAT ( periodCol, dateFormat ), labelChars ) )
    )
  VAR _Count  = COUNTROWS ( _DataIndexed )
  VAR _MaxVal = MAXX ( _DataIndexed, [Value] )

  // Layout
  VAR _PerPointX   = 32
  VAR _PadX        = 18
  VAR _Width       = 2 * _PadX + MAX ( 1, _Count - 1 ) * _PerPointX
  VAR _Height      = 86
  VAR _PadTop      = 10
  VAR _LabelBandH  = 26
  VAR _ChartBottom = _Height - _LabelBandH
  VAR _GoodColor   = "%23107C10" // Encoded #
  VAR _BadColor    = "%23A80000" // Encoded #
  VAR _LineColor   = "%230078D4" // Encoded #
  VAR _XStep =
    IF ( _Count > 1, DIVIDE ( _Width - 2 * _PadX, _Count - 1 ), 0 )

  VAR _HasData =
    _Count >= 2 && NOT ISBLANK ( _MaxVal )

  // Polyline points (forcé en en-US pour avoir des points décimaux)
  VAR _Points =
    CONCATENATEX (
      _DataIndexed,
      VAR _Idx  = [Idx]
      VAR _Val  = [Value]
      VAR _Norm = IF ( _MaxVal = 0, 0, DIVIDE ( _Val, _MaxVal ) )
      VAR _X    = _PadX + ( _Idx - 1 ) * _XStep
      VAR _Y    = _ChartBottom - _Norm * ( _ChartBottom - _PadTop )
      RETURN FORMAT ( _X, "0.0", "en-US" ) & "," & FORMAT ( _Y, "0.0", "en-US" ),
      " ",
      [Idx], ASC
    )

  // Dot markers
  VAR _Markers =
    CONCATENATEX (
      _DataIndexed,
      VAR _mIdx  = [Idx]
      VAR _mVal  = [Value]
      VAR _mNorm = IF ( _MaxVal = 0, 0, DIVIDE ( _mVal, _MaxVal ) )
      VAR _mX    = _PadX + ( _mIdx - 1 ) * _XStep
      VAR _mY    = _ChartBottom - _mNorm * ( _ChartBottom - _PadTop )
      RETURN
        "%3Ccircle cx='" & FORMAT ( _mX, "0.0", "en-US" )
        & "' cy='" & FORMAT ( _mY, "0.0", "en-US" )
        & "' r='2.2' fill='" & _LineColor & "' /%3E",
      "",
      [Idx], ASC
    )

  // Vertical guides
  VAR _GuideBottom = _ChartBottom
  VAR _Guides =
    CONCATENATEX (
      _DataIndexed,
      VAR _gIdx  = [Idx]
      VAR _gVal  = [Value]
      VAR _gNorm = IF ( _MaxVal = 0, 0, DIVIDE ( _gVal, _MaxVal ) )
      VAR _gX    = _PadX + ( _gIdx - 1 ) * _XStep
      VAR _gY    = _ChartBottom - _gNorm * ( _ChartBottom - _PadTop )
      RETURN
        "%3Cline x1='" & FORMAT ( _gX, "0.0", "en-US" )
        & "' y1='" & FORMAT ( _gY, "0.0", "en-US" )
        & "' x2='" & FORMAT ( _gX, "0.0", "en-US" )
        & "' y2='" & FORMAT ( _GuideBottom, "0.0", "en-US" )
        & "' stroke='%23CCCCCC' stroke-width='0.75' /%3E",
      "",
      [Idx], ASC
    )

  // Period labels
  VAR _LabelY = _Height - 16
  VAR _Labels =
    CONCATENATEX (
      _DataIndexed,
      VAR _lIdx = [Idx]
      VAR _lX   = _PadX + ( _lIdx - 1 ) * _XStep
      RETURN
        "%3Ctext x='" & FORMAT ( _lX, "0.0", "en-US" )
        & "' y='" & FORMAT ( _LabelY, "0.0", "en-US" )
        & "' text-anchor='middle' font-family='Segoe UI, sans-serif' "
		& "font-size='8' fill='%23666666'%3E"
        & [PeriodLabel]
        & "%3C/text%3E",
      "",
      [Idx], ASC
    )

  // Hover shades
  VAR _Shades =
    CONCATENATEX (
      FILTER ( _DataIndexed, [Idx] < _Count ),
      VAR _sIdx  = [Idx]
      VAR _sVal  = [Value]
      VAR _sNext = MAXX ( FILTER ( _DataIndexed, [Idx] = _sIdx + 1 ), [Value] )
      VAR _sNorm1 = IF ( _MaxVal = 0, 0, DIVIDE ( _sVal,  _MaxVal ) )
      VAR _sNorm2 = IF ( _MaxVal = 0, 0, DIVIDE ( _sNext, _MaxVal ) )
      VAR _sX1 = _PadX + ( _sIdx - 1 ) * _XStep
      VAR _sX2 = _PadX + _sIdx * _XStep
      VAR _sY1 = _ChartBottom - _sNorm1 * ( _ChartBottom - _PadTop )
      VAR _sY2 = _ChartBottom - _sNorm2 * ( _ChartBottom - _PadTop )
      VAR _sColor = IF ( _sNext >= _sVal, _GoodColor, _BadColor )
      RETURN
        "%3Cpolygon points='"
        & FORMAT ( _sX1, "0.0", "en-US" ) & "," & FORMAT ( _sY1, "0.0", "en-US" ) 
		& " "
        & FORMAT ( _sX2, "0.0", "en-US" ) & "," & FORMAT ( _sY2, "0.0", "en-US" ) 
		& " "
        & FORMAT ( _sX2, "0.0", "en-US" ) & "," & FORMAT ( _ChartBottom, "0.0", "en-US" ) 
		& " "
        & FORMAT ( _sX1, "0.0", "en-US" ) & "," & FORMAT ( _ChartBottom, "0.0", "en-US" )
        & "' fill='" & _sColor & "' fill-opacity='0.05' stroke='none' /%3E",
      "",
      [Idx], ASC
    )

  // Data labels
  VAR _ValueLabelY = _Height - 6
  VAR _DataLabels =
    CONCATENATEX (
      _DataIndexed,
      VAR _dIdx = [Idx]
      VAR _dVal = [Value]
      VAR _dX   = _PadX + ( _dIdx - 1 ) * _XStep
      RETURN
        "%3Ctext x='" & FORMAT ( _dX, "0.0", "en-US" )
        & "' y='" & FORMAT ( _ValueLabelY, "0.0", "en-US" )
        & "' text-anchor='middle' font-family='Segoe UI, sans-serif' font-size='7' "
		& "font-weight='bold' fill='%23333333'%3E"
        & FORMAT ( _dVal, "#,0" )
        & "%3C/text%3E",
      "",
      [Idx], ASC
    )

  // Assemble
  VAR _HoverExtras = IF ( hover, _Shades, "" )
  VAR _HoverLabels = IF ( hover, _DataLabels, "" )
  VAR _SVGContent =
    "%3Csvg xmlns='http://www.w3.org/2000/svg' viewBox='0 0 "
      & FORMAT ( _Width, "0", "en-US" ) & " " & FORMAT ( _Height, "0", "en-US" )
      & "' preserveAspectRatio='xMidYMid meet'%3E"
      & _HoverExtras
      & _Guides
      & "%3Cpolyline fill='none' stroke='" & _LineColor
      & "' stroke-width='1.5' stroke-linecap='round' stroke-linejoin='round' points='"
      & _Points
      & "' /%3E"
      & _Markers
      & _Labels
      & _HoverLabels
      & "%3C/svg%3E"

  RETURN
    IF (
      _HasData,
      "data:image/svg+xml," & _SVGContent,
      BLANK ()
    )

Finalement il faut aller ajuster les 4 mesures déjà existantes pour faire des appels à la fonction TrendSVG que nous venons de définir :

Units 6mo trend = TrendSVG([Units], 'Product Line Sales'[Month],6,3,"mmm",FALSE)
Units 6mo trend - hover = TrendSVG([Units], 'Product Line Sales'[Month],6,3,"mmm",TRUE)
Revenue 6mo trend = TrendSVG([Revenue], 'Product Line Sales'[Month],6,3,"mmm",FALSE)
Revenue 6mo trend - hover = TrendSVG([Revenue], 'Product Line Sales'[Month],6,3,"mmm",TRUE)

Comme ces 4 mesures retournent une image (au format vectoriel), il faudrait aller dans les options avancées du panneau des propriétés (dans la vue de modèle) et mettre la catégorie à URL de l’image pour chacune d’elles. Ceci peut être fait d’un coup en sélectionnant les 4 mesures avec la clé CTRL enfoncée.

Après nous pouvons suivre les instructions de la section Ajouter une image de niveau supérieur qui permet de rajouter les graphiques de l’évolution du nombre d’unités vendues et des revenus en utilisant les mesures créées (qui, elles, font appel à notre seule et unique UDF que nous avons intégrée au modèle).

Conclusion

Le visuel de cartes est à ma connaissance le visuel le plus complexe des visuels livrés avec Power BI Desktop (du moins en 2026). Le code présenté dans cet artiele permet de faire ce qui présenté dans notre vidéo et ainsi reproduire ce qu’on peut trouver dans l’article de Microsoft au niveau de l’approche pas à pas..

Le contenu lié au visuel de cartes est présenté dans le cours Microsoft Power BI Desktop : acquisition, modélisation et visualisation de données. Comme dans cet article (et dans le tutoriel de Microsoft) nous utilisons des mesures et des fonctions définies par l’utilisateur qui sont des concepts liés à la technologie DAX, ce qui est présenté ici est un des exercices dans le cours Introduction au langage DAX.

 © Tous droits réservés 2016-2025, HubFormation